Wikidata Straßen in SH

In Wikidata gibt es zahlreiche Einträge zu Straßen. Doch wie viele Straßen sind bereits in Wikidata verzeichnet? Dazu habe ich mir in Schleswig-Hostein ländliche Gegenden und als Beispiel für städtische Umgebung die Landeshauptstadt Kiel angesehen.

Da zwischen verschiedenen Arten von Straßen unterschieden wird, muss man sich die Klasse Straße ansehen. Straßen sind dann Instanzen von Unterklassen davon.

Schleswig-Holstein

In Schleswig-Holstein gibt es bislang nur sehr wenig. Ich habe mir den Bereich zwischen den Längengraden 9 und 10 und zwischen 54,1°N und 54,5°N angesehen. Mit dieser SPARQL-Abfrage kann man mit dem Wikidata Query Service danach suchen.

#defaultView:Map
SELECT DISTINCT ?street ?streetLabel ?municipality ?municipalityLabel ?geo
WHERE
{
  ?street wdt:P31/wdt:P279* wd:Q34442 .
  
  OPTIONAL {  ?street wdt:P131 ?municipality }  
  
  SERVICE wikibase:box
  {
    ?street wdt:P625 ?geo.
    bd:serviceParam wikibase:cornerWest 'Point(9.0 54.1)'^^geo:wktLiteral.
    bd:serviceParam wikibase:cornerEast 'Point(10.0 54.5)'^^ geo:wktLiteral.
  }
    
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,de". } 
}

Ausführen der SPARQL-Abfrage

Da sind nur 18 Einträge, die Karte sieht entsprechend leer aus:

Es könnte sein, dass es Straßen gibt, für die keine geografische Position angegeben ist. Die würden mit dieser Abfrage nicht gefunden. Aber eine SPARQL-Abfrage, die Instanzen von Straßen mit dem Bundesland Schleswig-Holstein in Beziehung setzt, ist so aufwändig, dass sie in einen Timeout läuft.

Kiel

Ganz anders sieht es hingegeben in der Landeshauptstadt Kiel aus. Kiel ist bereits sehr gut abgedeckt, es gibt 1067 Einträge zu Straßen.

#defaultView:Map
SELECT DISTINCT ?street ?streetLabel ?geo
WHERE
{
  ?street wdt:P31/wdt:P279* wd:Q34442 .
  
  SERVICE wikibase:box
  {
    ?street wdt:P625 ?geo.
    bd:serviceParam wikibase:cornerWest 'Point(10.04 54.26)'^^geo:wktLiteral.
    bd:serviceParam wikibase:cornerEast 'Point(10.21 54.43)'^^ geo:wktLiteral.
  }
    
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,de". } 
}

Ausführen der SPARQL-Abfrage

Bei der Abfrage habe ich die Bedingung liegt in der Verwaltungseinheit Kiel weggelassen, da ein großer Teil der Straßen nicht (direkt) der Stadt Kiel zugeordnet ist.

Das Straßenlexikon Kiel führt 1.553 Einträge auf. Damit sind also bereits 2/3 der Kieler Straßen in Wikidata verzeichnet.